1. Raízes de equações

1.1. Equações transcendentes

Algumas equações que dependem de uma variável podem ser resolvidas para obter um ou mais valores de que verificam a equação. Por exemplo, a equação + 4  + 3 = 0 tem duas soluções, = −1 e = −3, e a equação = 3 tem uma única solução = ln(3) = 1.0986… Existem equações, chamadas transcendentes, em que não é possível escrever uma expressão matemática para a solução e até pode ser difícil determinar se existem soluções e quantas. Por exemplo, a equação é uma equação transcendente; as suas soluções só podem ser calculadas de forma aproximada, usando métodos numéricos.

Para facilitar a procura das soluções de uma equação transcendente, é conveniente rescrevê-la na forma = 0; por exemplo, a equação pode ser escrita como . O problema de encontrar as soluções consiste então em encontrar as raízes da função , ou seja, os pontos onde o gráfico de corta o eixo das abcissas. No exemplo anterior, , o gráfico da função no intervalo obtém-se no Maxima com o seguinte comando:

(%i1) plot2d (x+1-tan(x), [x,0,2*%pi], [y,-5,5], [ylabel,"f(x)"]);

e o resultado (ver figura 1.1) mostra que nesse intervalo existem duas soluções, próximas dos valores = 1.1 e = 4.5.

Raízes de uma função
Figura 1.1: Gráfico da função .

No caso das funções contínuas, se em dois pontos diferentes e (admitindo < ), os sinais de e são diferentes, deve existir pelo menos uma raiz de no intervalo < < . No caso da figura 1.1, vê-se que é positiva mas é negativa; assim sendo, existe pelo menos uma raiz entre 0 e 1.3. Em = 3, é positiva, mas comparando com o valor negativo de não se pode concluir que existam raízes no intervalo 1.3 < < 3, já que nesse intervalo a função não é contínua.

1.2. Método de bissecções

Dados dois valores diferentes e , onde < e < 0 (ou seja, os sinais de e são diferentes), calculam-se o ponto meio e o valor da função nesse ponto, . Se for nula, é a raiz procurada; caso contrário, se o sinal de for o mesmo de substitui-se por , se o sinal de for o mesmo de substitui-se por e o processo repete-se indefinidamente até se obter um intervalo de comprimento muito reduzido:

(1.1)

onde /2 é a precisão com que se quer calcular a raiz. O valor final de será o que melhor aproxima o valor da raiz, com a precisão desejada.

Exemplo 1.1

Calcule a raiz de no intervalo 0 < < 1.3 com 2 casas decimais, usando o método de bisseções.

Resolução. Definem-se primeiro a função e os pontos iniciais:

(%i2) f(x) := float (x+1-tan(x))$
(%i3) [ x1, x2 ]: [ 1, 1.2 ]$

É importante usar float, para garantir que a função dê sempre um número e não uma expressão.

Os valores da função nos pontos iniciais são

(%i4) [ f(x1), f(x2) ];
(%o4)  [ 0.4425922753450977, -0.3721516221263186 ]

e como os sinais são diferentes, é possível usar o método das bissecções. O ponto meio e o valor da função nesse ponto são:

(%i5) [ xm: (x1+x2)/2, f(xm) ];
(%o5)  [ 1.1, 0.1352403427513478 ]

Como o sinal da função nesse ponto é positivo, substitui-se pelo ponto meio e repete-se o passo anterior:

(%i6) x1: xm$
(%i7) [ xm: (x1+x2)/2, f(xm) ];
(%o7)  [ 1.15, -0.08449694875532554 ]

Como agora a função é negativa, substitui-se por e repete-se o mesmo procedimento até se observar que o ponto meio não mude, até à segunda casa decimal:

(%i8) x2: xm$
(%i9) [ xm: (x1+x2)/2, f(xm) ];
(%o9)  [ 1.125, 0.03242872362782112 ]
(%i10) x1: xm$
(%i11) [ xm: (x1+x2)/2, f(xm) ];
(%o11)  [ 1.1375, -0.02411658214848611 ]
(%i12) x2: xm$
(%i13) [ xm: (x1+x2)/2, f(xm) ];
(%o13)  [ 1.13125, 0.00461493349083808 ]

O valor da raiz é = 1.13. Há que ter muita atenção a qual dos valores, ou , deve ser substituído por , para garantir que a raiz esteja sempre dentro do intervalo atual.

As iterações também podiam ter sido feitas mais rapidamente usando um ciclo while. Por exemplo, para encontrar a raiz com 3 casas decimais (precisão igual a 0.0005), começando com os mesmos valores iniciais, pode escrever-se:

(%i14) [ x1, x2 ]: [ 1.1, 1.2 ]$
(%i15) while abs (x2-x1) > 0.001 do
   (xm: (x1+x2)/2,
   if f(x1)*f(xm) > 0
    then x1: xm
    else x2: xm, print(xm))$
 1.15
 1.125
 1.1375
 1.13125
 1.134375
 1.1328125
 1.13203125

A raiz, com precisão de 3 casas decimais é 1.132. Observe-se que a função já tinha sido definida previamente e que já estava garantido que os sinais da função são diferentes nos dois pontos iniciais.

1.3. Método de falsa posição

No método das bissecções, se um dos valores ou estiver muito mais próximo de zero, espera-se que a raiz também esteja mas próxima do ponto ou em que a função está mais próxima de zero. Como tal, será mais eficiente usar o ponto em que a reta que passa pelos pontos (, ) e (, ) intersecta o eixo dos . Uma relação geométrica de semelhança entre triângulos permite demonstrar que é dado pela expressão

(1.2)

O método de falsa posição é semelhante ao método de bissecções, excepto que em vez de se usar o ponto meio de cada intervalo usa-se o ponto definido pela equação anterior.

Exemplo 1.2

Calcule a raiz de no intervalo 0 < < 1.3 com 3 casas decimais, usando o método de falsa posição.

Resolução. Aproveitando que a função é a mesma que já foi definida no exemplo da secção anterior, basta definir novamente os valores iniciais e modificar o ciclo while usado na secção anterior. É conveniente também guardar os valores da função já calculados, para evitar a redundância de serem calculados novamente a cada iteração:

(%i16) [ x1, x2 ]: [ 1.1, 1.2 ]$
(%i17) [ f1, f2 ]: [ f(x1), f(x2) ];
(%o17)  [ 0.1352403427513478 , -0.3721516221263186 ]

Os valores da função nos dois extremos do intervalo são armazenados nas variáveis e ; o resultado (%o17) permite também conferir que o sinal da função muda entre e . Como será claro nos resultados no fim deste exemplo, neste método a distância entre e não tem que ser pequena para que o valor esteja muito próximo da raiz. Assim sendo, a condição de paragem || < já não serve e no seu lugar deve comparar-se cada valor com o que tenha sido obtido na iteração anterior, que representaremos por . Inicialmente pode admitir-se que e são os próprios e .

(%i18) [ x0, xr ]: [ x1, x2 ]$

Para obter a precisão de 3 casas decimais, usa-se o comando:

(%i19) while abs (xr-x0) > 0.0005 do
   (x0: xr,
   xr: x2-f2*(x2-x1)/(f2-f1),
   fr: f(xr),
   print (x1, x2, xr),
   if f1*fr > 0
    then (x1: xr, f1: fr)
    else (x2: xr, f2: fr))$
 1.1  1.2  1.126654017428903
 1.126654017428903  1.2  1.131297851469829
 1.131297851469829  1.2  1.132100363591035
 1.132100363591035  1.2  1.132238851322909

Note-se que o valor da raiz com três casas decimais, 1.132, foi obtido na quarta iteração, enquanto que no método de bisseções foram precisas 7 iterações. Neste caso foram também apresentados os valores de e em cada iteração, para mostrar que o valor de permanece sempre em 1.2 e, como tal, não diminui muito.

1.4. Método de aproximações sucessivas

Quando a equação pode ser escrita na forma,

(1.3)

o método de aproximações sucessivas consiste em começar com um valor inicial e calcular a sequência , , … Dependendo da função e do valor inicial, em alguns casos a sequência aproxima-se de um limite, isto é, dentro de uma tolerância numérica dada, o valor de será igual a a partir de algum inteiro e, nesse caso será raiz de .

Exemplo 1.3

Encontre a raiz de mais próxima de = 1.1, com 3 casas decimais, usando o método de aproximações sucessivas.

Resolução. A equação pode também ser escrita:

Definindo a função e com valor inicial = 1.1, os seguintes 6 valores na sequência são:

(%i20) g(x) := float (tan(x)-1)$
(%i21) xi: 1.1$
(%i22) for i:1 thru 6 do (xi: g(xi), print (xi))$
 0.9647596572486523
 0.4429269858864537
 - 0.5256388221063686
 - 1.580073542507877
 106.7878688889125
 - 1.026287385725812

Esta sequência não parece ser convergente. O problema neste caso é que uma das condições para que a sequência seja convergente é que, na vizinhança da raiz que se pretende encontrar, o declive de seja menor que 1, que não é o que acontece neste caso:

(%i23) subst (x=1.1, diff (tan(x)-1, x));
(%o23)  4.860280510751842

O problema pode ser resolvido quando se consegue inverter a função usada. Ou seja, em vez de se usar pode usar-se a equação inversa, , que implica usar . No Maxima, a função inversa da tangente é a função atan. Com valor inicial = 1.1, os primeiros termos da sequência são:

(%i24) g(x) := float (atan(x+1))$
(%i25) xi: 1.1$
(%i26) for i:1 thru 6 do (xi: g(xi), print (xi))$
 1.126377116893798
 1.131203287160338
 1.132075737308623
 1.132233108872913
 1.132261484138675
 1.132266600045208

que converge rapidamente para o valor da raiz.

1.5. Método de Newton

Tal como no método de aproximações sucessivas, basta ter um valor inicial para criar uma sequência que se aproxima da raiz. As vantagens em relação ao método de aproximações sucessivas é que não é preciso escrever a equação = 0 na forma e a sequência converge em muitos mais casos. A desvantagem é que é preciso conhecer a derivada, , da função .

Se é uma função contínua e derivável, o valor de pode ser calculado, a partir do valor de , usando a série de Taylor

(1.4)

Se for suficientemente pequeno, os dois primeiros termos da série, apresentados na equação acima, são uma boa aproximação para o valor da série completa. Se o ponto for uma raiz, então = 0 e a equação anterior conduz à relação de recorrência,

(1.5)

que permite definir uma sequência de valores que deverá aproximar-se do valor da raiz.

Exemplo 1.4

Encontre a raiz de mais próxima de = 1.1, com 3 casas decimais, usando o método de Newton.

Resolução. A função já foi definida no comando (%i2) mas como é necessário também definir a sua derivada, vai repetir-se a definição de para comparar com a forma como deve ser definida:

(%i27) f(x) := float (x+1-tan(x))$
(%i28) df(x) := float (' '(diff (x+1-tan(x), x)));
(%o28)

Nas definições de e (derivada de ), a função float não é aplicada imediatamente, mas fica indicada na definição das funções e só será aplicada quando seja dado um valor a para calcular ou . Se a função float fosse aplicada imediatamente quando é definida, o resultado seria e se mais tarde fosse calculado o resultado seria , sem que fosse aproximada por um número de vírgula flutuante.

No entanto, no caso de diff(x+1+tan(x),x), pretende-se que a derivada seja calculada e simplificada imediatamente e o resultado usado para definir a função df(x), em vez de que diff(x+1+tan(x),x) seja calculado após ter sido dado um valor para (uma expressão como diff(1+1+tan(1),1) produz um erro). Usam-se dois apóstrofos seguidos: ' '(…), para forçar a que a expressão dentro dos parêntesis seja calculada e simplificada imediatamente.

Usando o valor inicial = 1.1, os seguintes 6 valores na sequência são:

(%i29) xi: 1.1$
(%i30) for i: 1 thru 6 do (xi: xi-f(xi)/df(xi), print (xi))$
 1.135033812277287
 1.13228759380087
 1.132267726299738
 1.132267725272885
 1.132267725272885
 1.132267725272885

Note-se a rapidez com que o método converge; após apenas 3 interações já se obtêm 4 casas decimais para a raiz e após a quinta iteração já é obtida a solução com o número máximo de casas decimais (15) que é possível obter com o formato de dupla precisão numérica usado pela função float.

1.6. Sistemas de equações transcendentes

O método de Newton pode ser generalizado facilmente para resolver um sistema de variáveis com equações contínuas e deriváveis. Por exemplo, no caso de duas equações com duas variáveis, = 0 e = 0, os primeiros termos nas séries de Taylor para as duas funções são:


(1.6)

Os índices nas derivadas indicam que e devem ser substituídas por (, ). Substituindo = 0 e = 0 e escrevendo o sistema em forma matricial, obtém-se,

(1.7)

onde é a matriz jacobiana:

(1.8)

calculada em e . As matrizes , e são:

(1.9)

A equação 1.7 permite definir a relação de recorrência para e ,

(1.10)

onde é a matriz inversa da matriz jacobiana.

Exemplo 1.5

Encontre os pontos de intersecção da circunferência = 3 com a hipérbole .

Resolução. Os gráficos da circunferência e da hipérbole podem ser traçados com o comando:

(%i31) plot2d ([sqrt(3-x^2), -sqrt(3-x^2), 1/x], [x,-3,3],
    [y,-2.25,2.25], [legend,false], [color,blue,blue,red]);
circunferencia-hiperbole
Figura 1.2: Gráficos da circunferência e a hipérbole .

O gráfico (figura 1.2) mostra que existem quatro pontos de intersecção, simétricos em relação às retas . Basta encontrar um desses quatro pontos, por exemplo, o que está mais próximo do ponto inicial = 0.5, = 1. Escrevendo as duas equações da forma = 0 e = 0, as duas funções são definidas pelas expressões,

(%i32) f: x^2+y^2-3$
(%i33) g: 1-x*y$

e a inversa da matriz jacobiana é:

(%i34) Jinv: invert (jacobian ([ f,g ], [ x,y ]))$

Define-se a função vectorial ,

(%i35) F(ri) := matrix ([ subst ([ x = ri[1][1], y = ri[2][1] ], f) ],
    [ subst ([ x = ri[1][1], y = ri[2][1] ], g) ])$

A seguir, dá-se o valor inicial para a matriz e realizam-se algumas iterações:

(%i36) ri: matrix ([0.5], [1])$
(%i37) for i:1 thru 6 do
    (ri: ri - subst ( [x = ri[1][1], y = ri[2][1] ], Jinv).F(ri),
    print (transpose (ri)))$
 [ 0.5833333333333334 1.833333333333333 ]
 [ 0.6089080459770115 1.633908045977011 ]
 [ 0.6178866256040898 1.61819150365287 ]
 [ 0.6180339655308434 1.618034011991991 ]
 [ 0.6180339887498943 1.618033988749895 ]
 [ 0.6180339887498949 1.618033988749895 ]

onde o ponto entre Jinv e F(ri) indica produto matricial.

Tendo em contra a simetria das soluções, as quatro soluções (, ) são então: (0.6180, 1.6180), (1.6180, 0.6180), (-0.6180, -1.6180) e (-1.6180, -0.6180).